_bswap.asm

Go to the documentation of this file.

;==----------------------------------------------------------------------------
; Efficient _bswap16/32/64 implementations.
; Dual mode (32/64 bit) assembly source.
; Copyright (c) Love Nystrom
;==----------------------------------------------------------------------------

TITLE Efficient _bswap16/32/64 implementations for 32 and 64 bit targets.

IFDEF RAX
    _WIN64 = 1
ELSE
    _WIN64 = 0
   .686P   ; Change this if you need to
   .XMM    ; Change this if you need to
   .MODEL FLAT
ENDIF

;==============================================================================
;  Common x86/x64 - Constants and parameterless functions
;==============================================================================

_TEXT SEGMENT
; No common code or data.
_TEXT ENDS

;==============================================================================
IF (_WIN64 eq 0) ; 32 bit version
;==============================================================================
ECHO === 32-BIT ASSEMBLY (ML) ===

_TEXT SEGMENT

;; Vanilla byte order swappers (x86)

PUBLIC __bswap16 ; extern "C" UINT16 _cdecl _bswap16( UINT16 W )
PUBLIC __bswap32 ; extern "C" UINT32 _cdecl _bswap32( UINT32 Val )
PUBLIC __bswap64 ; extern "C" UINT64 _cdecl _bswap64( UINT64 Val )

__bswap16   PROC
    mov     ax, word ptr [esp+4]
    xchg    al, ah
    ret
__bswap16   ENDP

__bswap32   PROC
    mov     eax, dword ptr [esp+4]
    bswap   eax
    ret
__bswap32   ENDP

__bswap64   PROC
    mov     edx, dword ptr [esp+4]
    mov     eax, dword ptr [esp+8]
    bswap   eax
    bswap   edx
    ret
__bswap64   ENDP

;; COLORREF / RGBQUAD byte order swappers (x86)

PUBLIC __swapRGB  ; extern "C" DWORD __cdecl _swapRGB( DWORD rgb );
PUBLIC __swapRGB2 ; extern "C" DWORD __cdecl _swapRGB2( DWORD rgb );

__swapRGB   PROC ; Preserves the high byte
    mov     eax, dword ptr [esp+4]
    mov     edx, eax
    bswap   eax
    shr     eax, 8 ; bgr
    and     edx, 0FF000000h
    or      eax, edx
    ret
__swapRGB   ENDP

__swapRGB2  PROC ; Clears the high byte
    mov     eax, dword ptr [esp+4]
    bswap   eax
    shr     eax, 8 ; bgr
    ret
__swapRGB2  ENDP

_TEXT ENDS

;==============================================================================
ELSE ; 64 bit version
;==============================================================================
ECHO === 64-BIT ASSEMBLY (ML64) ===

; Extern C assembly routines does NOT get an added underscore with MSVC + ML64.
; Hence the x64 assembly routines must be named *_exactly as the C prototypes_*.
;
; Fastcall is used regardless of prototype declaration!
; Arguments -> RCX, RDX, R8, R9, then stack.
;
; The four register args are backed by unused stack cells.
; Ergo, after std prologue the fifth argument is at [RBP+48].
;
; Normal fastcall stack cleanup convention (function pop args) is *not used*.
; Functions end with 'ret 0' even if they had stack args.
;
; RAX, RCX, RDX, R8, R9, R10, R11 are considered volatile.
; RBX, RBP, RDI, RSI, RSP, R12, R13, R14, and R15 are nonvolatile
; and must be saved and restored by a function that use them.
;
; frame$ = 10h ; Offset from rbp to first shadow arg after 'enter 0,0'
; x64 fastcall arguments:
;   rcx = arg1 (rbp+10h)
;   rdx = arg2 (rbp+18h)
;   r8  = arg3 (rbp+20h)
;   r9  = arg4 (rbp+28h)
;   [rbp+30h] = arg5 (rbp+30h)

_TEXT SEGMENT

;; Vanilla byte order swappers (x64)

PUBLIC _bswap16 ; extern "C" UINT16 _bswap16( UINT16 W )
PUBLIC _bswap32 ; extern "C" UINT32 _bswap32( UINT32 Val )
PUBLIC _bswap64 ; extern "C" UINT64 _bswap64( UINT64 Val )

_bswap16   PROC
    mov     ax, cx
    xchg    al, ah
    ret
_bswap16   ENDP

_bswap32   PROC
    mov     eax, ecx
    bswap   eax
    ret
_bswap32   ENDP

_bswap64   PROC
   mov     rax, rcx
   bswap   rax
    ret
_bswap64   ENDP

;; COLORREF / RGBQUAD byte order swappers (x64)

PUBLIC _swapRGB  ; extern "C" DWORD __cdecl _swapRGB( DWORD rgb );
PUBLIC _swapRGB2 ; extern "C" DWORD __cdecl _swapRGB2( DWORD rgb );

_swapRGB    PROC ; Preserves the high byte
    mov     eax, ecx
    bswap   eax
    shr     eax, 8 ; bgr
    and     ecx, 0FF000000h
    or      eax, ecx
    ret
_swapRGB    ENDP

_swapRGB2  PROC ; Clears the high byte
    mov     eax, ecx
    bswap   eax
    shr     eax, 8 ; bgr
    ret
_swapRGB2  ENDP

_TEXT ENDS

ENDIF ; _WIN64
END